Here the a big screen shot of all VID styles, this is a collage, the real window si smaller with a scroller (go to the picasa link to see it full size):
 |
| Da Rebol |
Then the real screenshot:
 |
| Da Rebol |
Then the source:
Rebol[]
view/title layout/size [
style draw-button box 12x12 effect [draw [pen black fill-pen red circle 6x6 5]]
a: panel [
across
tabs 14
text italic bold "You 'll find in this window all standard VID style sorte alphabetically."
return
text italic bold "The red circle indicate a style."
return
draw-button
panel [
backdrop http://www.rebol.com/view/nyc.jpg
vtext "This is the backdrop effect."
vtext "Image is scaled to fit the current window or panel"
]
return
tab
text "This is the (backdrop). Image is scaled to fit the current window or panel."
return
tab
text "It's better to use as first object of a pane, since all previous objects are covered"
return draw-button
panel [
backtile logo.gif
vtext red "This is the backtile effect"
vtext red "Image is repeated to fit the current window or panel"
]
return
tab
text "This is the backtile effect. Image is repeated to fit the current window or panel"
return
tab
text "It's better to use as first object of a pane, since all previous objects are covered"
return draw-button
anim rate 1 frames [http://www.rebol.com/view/nyc.jpg http://www.rebol.com/view/bay.jpg]
text "This is an animation (anim)"
return draw-button
area "This is area text (area)"
return draw-button
arrow
arrow right
arrow left
arrow down
text "These are arrows (arrow)"
return draw-button
banner "This is the banner text (banner)"
return draw-button
bar
text "This is a bar (bar)"
return draw-button
base-text "This is a base-text (base-text)"
return draw-button
body "This is a body text (body)"
return draw-button
box "This is a box (box), you can specify size and color"
box red "Box red"
return draw-button
btn "This a button (btn), it automatically fits the text"
return draw-button
btn-cancel text "This is a button for cancel, you can change text and color (btn-cancel)"
return draw-button
btn-enter text "This is a button for enter, you can change text and color (btn-enter)"
return draw-button
btn-help text "This is a button for help, you can change text and color (btn-help)"
return draw-button
button text "This is a button that doesn't resize automatically (button)"
return draw-button
check text "This is a check (check)"
return draw-button
TAB
check-line "This is a check (check-line). You can add directly text"
return
tab TAB check-line "It's useful to align many checks"
return draw-button
check-mark text "This is a check (check-mark)"
return draw-button
choice data ["a" "b" "c"]
text "This is a coiche button (choice)"
return draw-button
code "This is code text (code)"
return draw-button
drop-down data ["a" "b" "c"]
text "This is a drop-down button (drop-down)"
return draw-button
field "This is a field (field)"
return draw-button
h1 "This is (h1) text"
return draw-button
h2 "This is (h2) text"
return draw-button
h3 "This is (h3) text"
return draw-button
h4 "This is (h4) text"
return draw-button
h5 "This is (h5) text"
return draw-button
tab icon
text "This is an icon (icon), you can choose image and add a caption anc click it"
return
tab tab
icon logo.gif "Click here"
return draw-button
image logo.gif
text "This is an (image)"
return draw-button
info "This is an info field (info), not editable, but it's easy for copy and paste"
return draw-button
text "Press e key (key)"
key #"e" [alert "You pressed the e key, you can assign any action to the keys with the (key) function"]
return draw-button
lab "123456789012345678"
text "It's the label text (lab), fixed size. Useful for field label"
return text "it contains approximately 18 characters"
return draw-button
label "This is the label text (label). Useful for field label"
return draw-button
lbl "This is the labet text (lbl). Useful for field label"
return draw-button
led
text "This is a (led), you can light it"
led true
return draw-button
list 100x60 [across check text "Example" ]
text "This is a (list), it repeats the layout in order to fill the size indicated"
return draw-button
logo-bar
text "This is a logo bar (logo-bar)"
return draw-button
panel yellow [
button "Example"
text "This is a (panel). Very useful to arrange and modify layouts"
]
return draw-button
progress 0.3
text "This is a (progress) bar"
return draw-button
radio radio radio text "This are radio check button (radio). You can chaek only one per panel"
return draw-button
radio-line radio-line "This are radio check button (radio-line). "
return
draw-button
tab
radio-line "You can directly add text, useful to align text and check."
return
tab tab
radio-line "You can check only one per panel. Do you see it?"
return draw-button
rotary data [$1 $2 $3 ] Text "This is a rotary button (rotary), click to see the effect"
return draw-button
scroller
text "This is a scroller (scroller)"
return draw-button
slider text "This is a slider (slider)"
return draw-button
text "this is normal text"
return draw-button
text-list data ["One" "Two" "Three" ]
text "This is a (text-list)."
return draw-button
title "This is a title text (title)"
return draw-button
tog "This is a toggle button (tog), it has auto resize. If pressed, it remains pressed"
return draw-button
toggle
text "This is a toggle button (toggle). If pressed, it remains pressed"
return draw-button
tt "This is typewriter text (tt)"
return draw-button
txt "This is (txt) text"
return draw-button
vh1 "This is (vh1) text"
return draw-button
vh2 "This is (vh2) text"
return draw-button
vh3 "This is (vh3) text"
return draw-button
vh4 "This is (vh4) text"
return draw-button
vlab "Vlab"
text "This is the (vlab) text"
return draw-button
vtext "This is the (vtext)"
]
return
scroller 20X450 [
a/offset/y: to-integer ( 20 - (face/data * (a/size/y - 460) ))
show a
]
] 600x500 "VID styles"
No comments:
Post a Comment