Creating images and diagrams

This is a simple example of how to create a presentation image with few lines of code:

 Here the source:

REBOL [
    Title: "Block Diagram"
    Date: 24-Apr-2001
    Version: 1.0.1    
    Author:   ["Carl Sassenrath" "Massimiliano Vessi"]
    Purpose: {An example of REBOL code creating a useful diagram.}
]
i1: to-image layout [
    style box box font [valign: 'top ] edge [size: 2x2]
    b1: box 180x120 "View / Pro" effect [gradient 0x1 purple navy]
    at b1/offset + 20x30
    box 140x90 "View" effect [gradient 0x1 sky navy]
    at b1/offset + 40x60
    box 100x60 "Core" effect [gradient 0x1 pink   navy]
    at b1/offset + 0x118
    image 180x32 "REBOL Client" blue  
]
i2: to-image layout [
    style box box font [ valign: 'top ] edge [size: 2x2]
    b1: box 180x120 "Command" effect [gradient 0x1 wheat navy]
    at b1/offset + 20x30
    box 140x90 "Core / Pro" effect [gradient 0x1 leaf navy ]
    at b1/offset + 40x60
    box 100x60 "Core" effect [gradient 0x1 magenta navy]
    at b1/offset + 0x118
    image 180x32 "REBOL Server" blue
]
view layout [
    across
    space -40 ; this is to compact the result
    image i1
    box   180x180 effect [arrow rotate 270]
    box   80x180 "Internet" font [color: black size: 20 shadow: none ]
    box   180x180 effect [arrow rotate 90]    
    image i2
]